Codificación: Manipulación de controles en frmPedidos

gForm.Controls("TabDatos").item(3).Visible = False

Creación de nueva pestaña

Crearemos una nueva pestaña que albergará el histórico solicitado siguiendo los pasos del siguiente documento.

El código resultante es el siguiente:

  '    Creación de panel
  Set lPnl = gForm.Controls.Add("Threed.SSPanel", "Pers_panelHco")
  lPnl.Visible=True
  lPnl.autosize = 3
  lPnl.Object.Caption = ""
  '    Creación de la pestaña en sí
  gform.controls("TabDatos").InsertItem 100, "Hco. Firmas", lPnl.Hwnd, 1

Ocultación de menú "Albarán"

Siguiendo las especificaciones de la solución debemos ocultar dicho menú y condicionar su visibilidad a que la propiedad Pers_Validado del pedido esté activa.

Aquí será necesario primero ocultarlo al entrar en el formulario y, posteriormente, trabajar el evento de la carga del objeto para, si procede, hacerlo visible. Podríamos hacer exactamente lo mismo si quisiéramos dejarlo inactivo cambiando su propiedad correspondiente. Para el siguiente ejemplo simplemente lo ocultaremos.

Primero en el evento Initialize lo ocultamos, siguiendo los pasos indicados en el siguiente documento.

gForm.Controls("mnuMain").Tools("mnuAlbaran").visible = False

Ahora es necesario mostrarlo cuando se cumpla la condición de que esté totalmente validado. Recordemos que dicha validación, la de la cabecera del pedido, se realizará en un proceso independiente que lo marcará como tal una vez todas sus líneas hayan sido validadas.

Necesitamos añadir la visibilidad del mismo en un evento que se ejecute cada vez que cargamos un objeto. ¿Porqué no sirve en el Show o Initialize? Dentro de un objeto tenemos flechas de navegación entre registros, si no controláramos esta condición cada vez que cargamos un objeto serviría únicamente en la apertura de un único objeto y, lo que es peor, si lo dejáramos activo al navegar entre los mismos tendríamos el menú visible cuando no debiera estarlo.

Para ello usaremos el evento CargaObjeto, accesible mediante el control EnlaceObjeto.

Para ello simplemente leeremos la propiedad Value del campo que hemos añadido, "Validado", para mostrarlo u ocultarlo en función de su valor. Si hacemos click en el control nos dirá el nombre que se le ha asignado dentro del formulario:

Como este nombre es muy poco descriptivo lo renombraremos a algo que nos resulte más legible, con la opción del menú contextual Renombrar:

Nos solicitará el nuevo nombre (para este ejemplo le asignamos Pers_Validado) y, tras salir y volver a entrar de la pantalla, podremos ver el nuevo nombre aplicado:

Ahora que ya podemos trabajar con el campo añadiremos la funcionalidad básica inversa que antes hemos aplicado, siendo el código resultante el siguiente:

Sub CargaObjeto
  If gForm.Controls("Pers_Validado").Value Then
    gForm.Controls("mnuMain").Tools("mnuAlbaran").visible = True
  Else
    gForm.Controls("mnuMain").Tools("mnuAlbaran").visible = False
  End If
End Sub

NOTA: En nuestro ejemplo la ocultación del menú en el evento Initialize es redundante puesto que lo ocultamos en el evento de carga del objeto. Lo eliminamos para evitar código innecesario.

gForm.Controls("SeriePedido").ActivarScripts = True

  If aCombo.Name = "SeriePedido" Then
    If aCombo.Value <> "" Then
      lCodSerie = gcn.DameValorCampo("SELECT CodSerie FROM Series_Facturacion WHERE SerieFactura = " & aCombo.Value)
      If lCodSerie <> "" Then
        gForm.Controls("IdPedidoCli").Text = CStr(aCombo.Value) & " - " & CStr(lCodSerie)
      End If
    End If
  End If

Hemos hecho la primera referencia al control gCn. Recomendamos encarecidamente la lectura del siguiente artículo que lo explica en profundidad puesto que nos resultará de la máxima utilidad a la hora de hacer nuestras modificaciones.

Si bien esta modificación modificará el campo una vez hayamos cambiado el valor necesitamos una forma de rellenarlo automáticamente en los pedidos que creemos. Anteriormente hemos usado el evento CargaObjeto. Haremos lo mismo con el evento NuevoObjeto.

Sub NuevoObjeto
  lSerieFacturacion = gForm.Controls("SeriePedido").Value
  lCodSerie = gcn.DameValorCampo("SELECT CodSerie FROM Series_Facturacion WHERE SerieFactura = " & lSerieFacturacion)
  If lCodSerie <> "" Then
    gForm.Controls("IdPedidoCli").Text = CStr(lSerieFacturacion) & " - " & CStr(lCodSerie)
  End If
End Sub

Sub AsignacionValorPedCli()
  lSerieFacturacion = gForm.Controls("SeriePedido").Value
  lCodSerie = gcn.DameValorCampo("SELECT CodSerie FROM Series_Facturacion WHERE SerieFactura = " & lSerieFacturacion)
  If lCodSerie <> "" Then
    gForm.Controls("IdPedidoCli").Text = CStr(lSerieFacturacion) & " - " & CStr(lCodSerie)
  End If
End Sub

Llamamos a dicha subrutina en los sitios que corresponda con una simple instrucción.

AsignacionValorPedCli()

gForm.Controls("Origen").ActivarScripts = True

If aCombo.Name = "Origen" Then
    If aCombo.Value = "SubCanal 0" Then
      If gForm.Controls("Observaciones").Text = "" Then
        gForm.Controls("Observaciones").Text = "TEXTO MODIFICADO POR Origen"
      Else
        gForm.Controls("Observaciones").Text = gForm.Controls("Observaciones").Text & VbCrlf & "TEXTO MODIFICADO POR Origen"
      End If
    End If
  End If

Añadimos una simple comprobación para evitar introducir una línea en blanco antes del texto para respetar lo que hubiera podido estar introducido en el control.

Modificación de observaciones (tras modificar SeriePedido)

Esta modificación se basa exactamente en lo mismo que las anteriores con la particularidad que vamos a tratar el campo en el evento AfterUpdate de un campo de texto, no de un combo, aunque su funcionamiento es exactamente el mismo.

  If aTexto.Name = "IdPedidoCli" Then
    lSerieFacturacion = gForm.Controls("SeriePedido").Value
    lCodSerie = gcn.DameValorCampo("SELECT CodSerie FROM Series_Facturacion WHERE SerieFactura = " & lSerieFacturacion)
    lValorTeorico = lSerieFacturacion & " - " & lCodSerie
    If lValorTeorico <> aTexto.Text Then
      lTextoObs = "Se ha modificado el valor de Pedido Cli"
      If gForm.Controls("Observaciones").Text = "" Then
        gForm.Controls("Observaciones").Text = CStr(lTextoObs)
      Else
        gForm.Controls("Observaciones").Text = gForm.Controls("Observaciones").Text & VbCrlf & CStr(lTextoObs)
      End If
    End If
  End If

El código completo hasta el momento de este formulario se puede ver en el fichero adjunto frmPedidos_1.txt.

Codificación: Manipulación de grids en frmEmpleados >